エクセルVBAでProperty Letプロシージャを使ってプロパティ設定をする方法

photo credit: Thomas Hawk It’s Too Late to Say You’re Sorry Now via photopin (license)

みなさん、こんにちは！
タカハシ(@ntakahashi0505)です。

「初心者でもわかるエクセルVBAのクラスモジュール」について連載でお送りしております。

前回の記事はこちらです。

エクセルVBAでプロパティを他のモジュールからアクセスできないようにする方法

「初心者でもわかるエクセルVBAのクラスモジュール」をテーマに連載をお伝えしています。今回はエクセルVBAでプロパティをプライベート変数で作成して他のモジュールからアクセスできないようにする方法です。

クラスにプライベート変数を宣言して、他のモジュールからアクセスできないプロパティを作成しました。

…って、他のモジュールからアクセスできないんじゃ、プロパティとして意味ないんじゃ…？

って思います？

私もそう思っていました。

ですが、大丈夫です。

直接アクセスできないのですが、間接的にはアクセスできるんです。

Propertyプロシージャを使ってね。

ということで、今回はエクセルVBAでProperty Letプロシージャを使ってプロパティ設定をする方法をお伝えします。

では、行ってみましょう！

前回のおさらい
1. なぜコンパイルエラーが出ているのか：これまでの経緯
他のモジュールからプライベート変数にアクセスする方法
Property Letプロシージャとは
Property Letプロシージャでプロパティを設定する
1. Property Letプロシージャによるプロパティを確認する
2. 標準モジュールから呼び出して確認をする
まとめ
連載目次：初心者でもわかる！エクセルVBAでクラスを作ろう

前回のおさらい

前回までのおさらいです。

まず、以下のようなエクセル表がありまして、この1行分のデータを表すクラスの作成を目指しています。

クラスPersonの定義をするクラスモジュールには以下のようなコードが書かれています。

Private id_ As String
Public FirstName As String
Public Gender As String
Public Birthday As Date

Public Sub Greet()
    MsgBox Me.FirstName & "です、こんにちは！"
End Sub

Public Property Get IsMale() As Boolean
    IsMale = (Me.Gender = "male")
End Property

エクセル表の見出しに対応するプロパティをモジュール変数として定義。あと、便利そうなメソッドとプロパティを一つずつ追加しています。

確認用のSubプロシージャを記述している標準モジュールがこちらです。

Sub MySub()

Dim p As Person: Set p = New Person

Dim i As Long: i = 2
With Sheet1
    p.Id = .Cells(i, 1).Value
    p.FirstName = .Cells(i, 2).Value
    p.Gender = .Cells(i, 3).Value
    p.Birthday = .Cells(i, 4).Value
End With

Stop
'p.Greet

End Sub

ただ、残念現在は以下のようなコンパイルエラーが発生してしまうという状況なのです。

なぜコンパイルエラーが出ているのか：これまでの経緯

事の発端はこうです。

まず、クラスPersonのIdプロパティはもともとはパブリック変数として定義していました。

ただ、パブリック変数で定義しちゃうと、Idプロパティを一度設定した後も、何度でも上書き、変更ができてしまう…それって、Idとしてドウなの？というわけです。

それを解決するために、Idプロパティをプライベート変数「id_」として定義をするように変更しました。

ですが、そうすると他のモジュールからアクセスできないわけで、インスタンスを生成したときに最初の正しいIdを設定するときにもアクセスできない…

こんなジレンマを抱えています。

それを解決するのが、今回の記事というわけです。

他のモジュールからプライベート変数にアクセスする方法

では、他のモジュールからプライベート変数にアクセスする方法について、ちょっと状況を整理しながら作戦を練りましょう。

まず、クラスモジュールPersonに定義したプライベート変数id_は、他のモジュールからはアクセスできません。これについてはお伝えした通りです。

逆に考えてみましょう。

じゃあ、プライベート変数id_はどこからアクセスできるんでしたっけ？？

と考えると、ほらクラスモジュールPerson内に記述したいずれかのプロシージャからであれば、変数id_はアクセスが可能なわけです。

外側からがダメなら、内側から攻めればよいのですよ…！

で、そのPersonモジュール内に置くプロシージャですが、これを「パブリック」にしてあげれば、他のモジュールから呼び出し可能で、かつ引数を受け取れます。

つまり、直接プライベート変数にアクセスするのではなく、何らかのプロシージャに値を渡して、そのプロシージャ内でプライベート変数を書き換えるんですね。

このように、プライベート変数の橋渡し役のプロシージャとして、Propertyプロシージャを使うことができるというわけです。

プライベート変数から値を取得するには、以前の記事で紹介したProperty Getプロシージャを使います。

そして、プライベート変数に値を設定するには、今回紹介するProperty Letプロシージャを使うのです。

このように、Propertyプロシージャによる迂回作戦でプロパティにアクセスするんですね。よく考えたものですね。

Property Letプロシージャとは

では、Property Letプロシージャとは何か、またその使い方について見ていきましょう。

Property Letプロシージャとは、プロパティを設定するときの手続きです。

つまり、プロパティを設定しようとしたときに、手続きを呼び出すことができます。

書き方はこうです。

Property Let プロシージャ名(仮引数 As 型)
　’処理
End Property

Property Letプロシージャを定義すると、そのプロシージャ名がプロパティ名になります。

そして、例えば「Personオブジェクト.プロパティ = 値」というように、インスタンスに何らかの値を設定しようとしたときに、その値を引数としてProperty Letプロシージャが呼び出されることになります。

ちなみに、設定するものがオブジェクト参照の場合は、Property Setプロシージャを使います。

Property Letプロシージャでプロパティを設定する

実際に、Personクラスでの例を使ってProperty Letプロシージャを作ってみましょう。

以下のProperty LetプロシージャIdを、クラスモジュールPersonに追加します。

Public Property Let Id(ByVal newId As String)
    If id_ <> "" Then
        Debug.Print "Idは上書きすることはできません"
    Else
        id_ = newId
    End If
End Property

プロパティIdが設定される際に、Property LetプロシージャIdが呼び出され、かつプロパティの設定値をnewIdとして受け取ります。

If文がありますが、既にプライベート変数id_に何らかの空文字以外の文字列が格納されていれば、イメディエイトウィンドウにその旨通知するだけで、何もしません。

さもなくば、プライベート変数id_は初期状態ということになりますので、受け取った引数id_を格納します。

こうすることで、初回のIdの設定はできるが、それ以降の上書きはされないプロパティを作ることができるということになります。

Property Letプロシージャによるプロパティを確認する

F2 キーを押して、オブジェクトブラウザで様子を見てみましょう。

Personクラスには、プライベート変数で宣言したプロパティ「id_」と、Property Letプロシージャで定義したプロパティ「Id」の2つが存在していますね。

前回、プライベート変数名を小文字+アンダースコアの形式にしたのは、これが理由です。

Personクラスモジュール内で実際にデータを持つのは変数id_
他のモジュールからアクセスをするのはProperty LetプロシージャId

と使い分けをする必要があるからですね。

他のモジュールからアクセスさせないように、プライベート変数として宣言する場合は、小文字+アンダースコアという名前することで、上記の役割を明確化する慣習があるということです。

標準モジュールから呼び出して確認をする

では、実行をして確認してみましょう。

標準モジュールModule1のSubプロシージャを以下のように変更して実行してみます。

Sub MySub()

Dim p As Person: Set p = New Person

Dim i As Long: i = 2
With Sheet1
    p.Id = .Cells(i, 1).Value
    p.FirstName = .Cells(i, 2).Value
    p.Gender = .Cells(i, 3).Value
    p.Birthday = .Cells(i, 4).Value
End With

p.Id = "Hoge"
Stop
'p.Greet

End Sub

Stopステートメントで中断しているときの様子を確認すると、以下のようになります。