エクセルVBAでPowerPointでタイトルを変更しながらスライドを大量に生成する

photo credit: 80.000 baby chickens via photopin (license)

みなさん、こんにちは！
タカハシ(@ntakahashi0505)です。

エクセルVBAでPowerPointを操作する方法についてお伝えしています。

前回の記事はコチラ。

エクセルVBAでPowerPointスライド上のシェイプ一覧を取得する

エクセルVBAでPowerPointを操作する方法についてシリーズでお伝えしています。今回はPowerPointスライドのシェイプ一覧を取得する方法とShapeとShapesオブジェクトについてです。

エクセルVBAでPowerPointのテキストボックスに文字を入力する方法についてお伝えしました。

さて、ちょっと方向を変えましてスライドの操作をしていきたいと思います。

数ページのPowerPoint資料だったら良いのですが、例えば「都道府県別のスライドを作りたい」などといったとき、それだけのスライドを用意してスライドのタイトルを変更するだけでもちょっとダルいですよね…。

そんな時は、エクセルVBAに任せてスライドを複製＆テキスト変更をしてしまえばOKです。

ということで、今回はエクセルVBAでPowerPointスライドをスライドタイトルを変更しながら生成する方法についてお伝えします。

PowerPointのスライドを複製する
スライドタイトルを指定しながら複数スライドを生成する
まとめ
連載目次：エクセルVBAでグラフとPowerPointを操作する

PowerPointのスライドを複製する

今回はこちらのPowerPointをひな形として利用していきます。

何の変哲もないスライドが一枚…「タイトル」と書かれたテキストボックスがスライドタイトルです。

スライドを複製するのはとっても簡単です。

スライドオブジェクトに対して、Duplicateメソッドを使います。

PowerPointスライドオブジェクト.Duplicte

例えば、こんなプログラムですね。

Sub PowerPointのスライドを複製する()

Dim ppApp As New PowerPoint.Application
ppApp.Visible = True

Dim ppPrs As PowerPoint.Presentation
Set ppPrs = ppApp.Presentations.Open(ThisWorkbook.Path & "\ひな形.pptx")

ppPrs.Slides(1).Duplicate  '1ページ目を複製
ppPrs.Slides(1).Duplicate  '1ページ目を複製

'ppApp.Quit
'Set ppApp = Nothing

End Sub

こちらを実行しますと

このように２枚の複製ができます。Duplicateメソッドを二回やっているからっすね。簡単です。

スライドタイトルを指定しながら複数スライドを生成する

では、これをさらに発展させていきましょう。

スライドタイトルのテキストを指定しながら大量のスライドを複製していきます。

例えば、こんなエクセルシートを用意します。

各都道府県名がリストされているだけですね。

この都道府県名が各スライドのスライドタイトルになるように複製していきます。

先ほどのプログラムの9,10行目を以下のプログラムに差し替えてみましょう。

Dim countSld As Long 'スライド数

Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Sheet1")

Dim i As Long
i = 3

Do While ws.Cells(i, 1).Value <> ""

    countSld = ppPrs.Slides.count '現在のスライド数をカウント
    ppPrs.Slides(countSld).Duplicate  '最終ページを複製
    ppPrs.Slides(countSld + 1).Shapes(3).TextFrame.TextRange.Text = ws.Cells(i, 2).Value '最終ページのスライドタイトルに都道府県名

    i = i + 1
Loop

なお、テキストを入力したいシェイプのインデックス番号に関しては「3」です。こちらの方法で目的のインデックス番号を知ることができます。