エクセルVBAでQueryTableオブジェクトを使って高速にCSVを取り込む方法

みなさん、こんにちは！
フジタニ(@libartweb)です。

CSVの取り込みをエクセルVBAで行う場合は、ループを使って1行ずつ読み込んでいくのが一般的な方法です。

今回は、そんなCSV取り込みを、ループを一切使わずに、一発で取り込むもう一つの方法を紹介します。

大きなCSVの取り込み処理が月に数回、もしくは1日に何回も…という高い頻度で実施される方、速度をもっと速くしたい！という方は必見です！

CSVの取り込みがもっとラクに、速くできるようになりますよ！

通常のCSV取り込みの流れ
QueryTableオブジェクトによるCSV取り込み
まとめ、次回予告
連載目次：エクセルVBAのQueryTableで高速にCSVを取り込む

通常のCSV取り込みの流れ

以下の記事でも紹介していますが、通常はCSVを、エクセルVBAでオープンした後、1行ずつセルに書き出していくのが一般的です。

100行や200行など小さなCSVだと処理速度の差は全く体感できないので、ループを使う方法で全く問題ありません。もし、大きなファイルを頻繁に扱う方は今回紹介する方法を検討してみてください！

エクセルVBAでCSVデータをカンマで区切ってワークシートに取り込む方法

エクセルVBAでCSVを取り込む方法です。今回は、Splitという命令と配列を使ってCSVのレコードをカンマで区切ってワークシートに転記をしていく方法について解説をしていきます。

過去の記事で紹介したソースコードは下記の通りです。

ループの中にループがあるので、CSVが大きいとどうしても処理速度で不利になってしまう場合があります。

'==================================
'CSVをループを使用して取り込むサンプル
'==================================
Sub getCSV()

    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets(1)
    
    Dim strPath As String
    strPath = "C:\Users\Noriaki\Dropbox\40_ブログ\vba-csv\test\ラーメン店アンケート.csv"
    
    Dim i As Long, j As Long
    Dim strLine As String
    Dim arrLine As Variant 'カンマでsplitして格納
    
    Open strPath For Input As #1 'CSVをオープン
    
    i = 1
    
    Do Until EOF(1)
       
        Line Input #1, strLine
        arrLine = Split(strLine, ",") 'strLineをカンマで区切りarrLineに格納
       
        For j = 0 To UBound(arrLine)
           
            ws.Cells(i, j + 1).Value = arrLine(j)
       
        Next j
        i = i + 1
    Loop
    
    Close #1

End Sub

QueryTableオブジェクトによるCSV取り込み

ループを使ったCSV取り込みが一般的であり、実際に使われている方もたくさんいらっしゃると思います。今回はあまり知られていない、QueryTableオブジェクトを使いますので、まずはその概要について解説します。

最初にサンプルコードを記載します。

Private Sub csvImport()
    Dim strPath As String
    Dim qtCsv   As QueryTable
    
    strPath = "C:\Users\hirom\Desktop\test.csv"
    Set qtCsv = Sheet1.QueryTables.Add(Connection:="TEXT;" & strPath, _
        Destination:=Sheet1.Range("A1")) '取り込むCSVパスと、取り込み先のシート、セルを指定
    
    With qtCsv
        .TextFileCommaDelimiter = True 'カンマ区切りの指定
        .TextFileParseType = xlDelimited   ' 区切り文字の形式
        .TextFileColumnDataTypes = Array(1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1, 1) '項目（列）の型指定
        .TextFileStartRow = 1 '開始行の指定
        .TextFileTextQualifier = xlTextQualifierDoubleQuote '引用符の指定
        .TextFilePlatform = 932 '文字コード指定
        .Refresh 'QueryTablesオブジェクトを更新し、シート上に出力
        .Delete 'QueryTables.Addメソッドで取り込んだCSVとの接続を解除
    End With

End Sub

書き方がループを使用したCSV取り込みの方法とは大きく異なっており？？？となっていることでしょう。では解説していきます。