エクセルVBAでCSVを高速に取り込むQueryTableオブジェクト使用時の注意点

みなさん、こんにちは！
フジタニ(@libartweb)です。

エクセルVBAでCSVを高速に取り込むQueryTableオブジェクトについて、各メソッド、プロパティの使い方をシリーズでお伝えしてきました。

前回の記事はこちら

エクセルVBAで高速にCSVを取り込むQueryTableオブジェクトの最終処理

エクセルVBAでCSVを高速に取り込むことができるQueryTableオブジェクト。最終処理として非常に重要なQueryTable.Deleteメソッドについて解説します。忘れると不具合を招く非常に重要なメソッドです！

QueryTableオブジェクトの速さ、便利さを知って頂けたと思います。

今回はそんなQueryTableオブジェクトを使用する際に気をつけて頂きたいことを紹介します！

思わぬバグを防ぐことはもちろん、コーディングの時間短縮にもつながります。引き出しを増やすためにも、是非参考にしてみてください。

中身が空のCSVへの対応
1. 中身が空のCSVを取り込もうとした場合のエラー
2. CSVが空かどうかを取り込み前に確認する方法
取り込むCSVの選択方法
1. 自動でファイルを選択する
2. ファイル選択ダイアログで選択する
まとめ
連載目次：エクセルVBAのQueryTableで高速にCSVを取り込む

中身が空のCSVへの対応

QueryTableオブジェクトを使用したCSV取り込みにおける、最大のつまずきポイントかも知れません。

QueryTableオブジェクトでは、空のCSVを取り込むことができないのです。

中身が空のCSVを取り込もうとした場合のエラー

試しに空のCSVで実行してみましょう。

「メモリが不足しています」

わかりづらいエラー！どう見ても、メモリ関連に問題があるようなエラーですから、知らない人はこれを見て、原因が「CSVが空であること」をすぐに見抜くことは難しいかもしれないですね…

では、空のCSVを取り込むことも想定してコーディングしちゃいましょう。

CSVが空かどうかを取り込み前に確認する方法

CSVの行数カウントには様々な方法がありますが、今回はCSVが空かどうか？を調べるだけですので最も簡単なプログラムを紹介します。サンプルコードは以下の通りです。

Private Sub csvImport()
 
    Dim strPath As String
    Dim qtCsv   As QueryTable
    
    strPath = "C:\Users\hirom\Desktop\test.csv"

    If Dir(strPath) = "" Then
        MsgBox (strPath & "は存在しません")
        Exit Sub
    End If
    
    If isCsvEmpty(strPath) = True Then
        MsgBox (strPath & "は中身が空です。")
        Exit Sub
    End If
    
    Set qtCsv = Sheet1.QueryTables.Add(Connection:="TEXT;" & strPath, _
        Destination:=Sheet1.Range("A1")) '取り込むCSVファイルパスと、取り込み先のシート、セルを指定
    
    With qtCsv
        .TextFileCommaDelimiter = True 'カンマ区切りの指定
        .Refresh 'QueryTableオブジェクトを更新し、シート上に出力
        .Delete 'QueryTableオブジェクトを削除
    End With
End Sub

Private Function isCsvEmpty(ByVal strPath As String)
    Dim myFileNo As Integer
    
    isCsvEmpty = True
    myFileNo = FreeFile
    Open strPath For Input As #myFileNo
        If EOF(myFileNo) = False Then
            isCsvEmpty = False
        End If
    Close #myFileNo
    
End Function

これまでに紹介してきたQueryTableのソースコード内に、CSVが空かどうか？をチェックする「isCsvEmpty」というFunctionを追加しました。

CSVが空かどうかを判定して、空なら処理を中断する処理です。

それでは「isCsvEmpty」で使用しているステートメント、関数を紹介していきます。

ステートメント	詳細
Open	CSVやテキストファイルをパソコン内部で開く
Close	Openステートメントで開いたファイルを閉じる

関数	詳細	引数	返り値
FreeFile	ファイル番号を返す	範囲番号	Integer
EOF	ファイルの読み込み位置が末尾かどうかを返す	ファイル番号	Boolean

ステートメント、関数の使い方

Open CSVのフルパス For 入力モード As #ファイル番号

通常テキストやCSVなどを取り込むときはWorkbook上に取り込みますが、Openステートメントを使用することでWorkbookを新しく作成せず、パソコン内部で開くことができます。

引数	詳細
CSVのフルパス	空であるか確認したいCSVのフルパス
入力モード	CSVの場合はシーケンシャル入力モードを表す「Input」を指定。（先頭から順番に読み込むモード）
#ファイル番号	CSVに割り当てる番号