VBScriptでWEBスクレイピング！アメブロの管理画面に自動でログインする方法

こんにちは！あつもり(@atumori17)です。

VBScriptでIEを操作してWEBスクレイピング！の第9回目で～す。
前回は「ページ内にあるテーブル要素を取得してCSVファイルとして書き出す」ところまでやりました。

VBScriptでWEBスクレイピング！テーブル要素を取得してCSVファイルで書き出す

ページ内にあるテーブル要素を抜き出してCSVファイルとして書き出す方法を紹介します。CSVファイルで書き出しておけば、エクセルなどで簡単に開けるので便利ですよ。getElementsByTagNameメソッドでtr要素のコレクションを取得しFor Each文を使いtr要素、td要素を取り出していきます。

今回は「アメブロのブログ管理画面に自動でログインする」方法を紹介します。

IEを使ってアメブロのログイン画面にアクセスし、ID、パスワードを入力させ自動ログインする方法を説明していきます。

アメブロの管理画面に自動ログインするスクリプト
プログラムコードの解説
アメブロ管理画面に自動ログインしてみる
まとめ
連載目次：VBScriptでお手軽WEBスクレイピング

アメブロの管理画面に自動ログインするスクリプト

ではまずスクリプトの全文を紹介します。テキストエディタを開き下記のコードを入力します。全て入力し終わったら「アメブロ自動ログイン.vbs」のファイル名でデスクトップに保存します。

Option Explicit

    Dim objIE
    Dim el

    Set objIE = CreateObject("InternetExplorer.Application")
    objIE.Visible = True

    'IEを開く
    objIE.navigate "http://kuchikomi.ameba.jp/ucs/logininput"
    
    'ページが読み込まれるまで待つ
    Do While objIE.Busy = True Or objIE.readyState <> 4
        WScript.Sleep 100        
    Loop
    
     'a要素にログインがあったらクリックする
    For each el In objIE.document.Links             
        if instr(el.innerText,"ログイン") then
            el.click
            exit for    
        end if
    next    
    
    'ページが読み込まれるまで待つ
    Do While objIE.Busy = True Or objIE.readyState <> 4
        WScript.Sleep 100        
    Loop    
    
     'IDとパスワードを入力する
     With objIE.document      
        .getElementsByName("accountId")(0).Value = "TEST@gmail.com"   
        .getElementsByName("password")(0).Value = "1111"        
     End With     
     
    Dim objbutton
     
    'button要素をコレクションとして取得
    Set objbutton = objIE.document.getElementsByTagName("button")    
    
    'button要素にログインがあったらクリックする
    For each el In objbutton
        if instr(el.innerText,"ログイン") then
            el.click
            exit for
        end if         
    next

プログラムコードの解説

全体の流れは以下のようになります。

IEでアメブロのログイン画面を開く
a要素をコレクションとして取得する
ログインボタンをクリックする
ID、パスワードを入力する
button要素をコレクションとして取得する
ログインボタンをクリックする

まず1ページ目はログインボタンをクリックするだけの処理を行います。すると2ページ目に遷移するので、ID、パスワードを入力し再びログインボタンをクリックするという流れになります。

次の画像を見るとイメージが沸きやすいと思います。

a要素のコレクションからログインを探しクリックする

まずはFor each文でコレクションとして取得したa要素ぶんだけ繰り返す処理を行います。続いてinnerTextプロパティでa要素をテキストとして取得し「ログイン」という文字があるかを調べます。指定した文字が含まれているかを調べるにはinstr関数を使います。

instr(要素,”検索する文字列”)

上記プログラムコードの17～23行目になります。

     'a要素にログインがあったらクリックする
    For each el In objIE.document.Links             
        if instr(el.innerText,"ログイン") then
            el.click
            exit for    
        end if
    next

「ログイン」が見つかったらclickメソッドを使ってリンクをクリックさせます。

要素.click

最後にexit forでループから抜けます。

exit for

要素をコレクションとして取得する方法については過去の記事で紹介していますので参考にしてみてください。